PDLを使ってみよう

自己紹介

• TwitterID

  @techno_neko

• お仕事

  組み込み系

• 所属

  Hokkaido.pm

PDLを使ってみよう

• PDLって？

  簡単な紹介

• 使ってみよう

  こんな感じ

• まとめ

  ちゃんとやります！

PDLって？

• 何の略？

  Perl Data Language

• 公式サイト

  http://pdl.perl.org/

• 何が出来るの？

  行列の計算とか簡単にできる！

使ってみよう（１）

• インストール

  $ cpanm PDL

• 変数を作る

  use v5.10;
  use PDL;
  
  my $a = pdl( 1, 2, 3 );
  say ref $a; # PDL
  say $a;     # [1 2 3]
  
  # 上と同じ
  my $b = pdl [ 1, 2, 3 ];
  say $b;     # [1 2 3]
  

使ってみよう（２）

こういうのが簡単！

use v5.10;
use PDL;

my $a = pdl( 2, 4 );
say '$a     => ', $a;     # $a     => [2 4]
say '$a + 2 => ', $a + 2; # $a + 2 => [4 6]
say '$a - 2 => ', $a - 2; # $a - 2 => [0 2]
say '$a * 2 => ', $a * 2; # $a * 2 => [4 8]
say '$a / 2 => ', $a / 2; # $a / 2 => [1 2]

使ってみよう（３）

行列の宣言

use v5.10;
use PDL;
use PDL::Matrix;

my $a = mpdl( [0, 1, 2], [2, 1, 0], [0, 0, 2] );
say ref $a; # PDL::Matrix
say $a;
#[
# [0 1 2]
# [2 1 0]
# [0 0 2]
#]

使ってみよう（４）

逆行列の計算

use v5.10;
use PDL;
use PDL::Matrix;

my $a = mpdl( [0, 1, 2], [2, 1, 0], [0, 0, 2] );
my $b = inv $a;
say $b;
#[
# [-0.5    1    0]
# [ 0.5    0    0]
# [ 0.5   -1  0.5]
#]

使ってみよう（５）

逆行の積

use v5.10;
use PDL;
use PDL::Matrix;

my $a = pdl( [0, 1, 2], [2, 1, 0], [0, 0, 2] );
my $b = inv $a;
my $c = $a x $b; # 'x'を使ってる点に注意
say $c;
#[
# [1 0 0]
# [0 1 0]
# [0 0 1]
#] 

まとめ

• で、何に使えるの？

• 音とか鳴らないの？

• ねぇ、音とか（略

帰ってきたPerl meets beats

Perl meets beatsって？

• PerlでWaveファイルを出力する話

  リズムマシンのような音を出す方法について

• WEB+DB PRESS Vol.69に掲載

• Perl Hackers Hubで公開済み

  第15回　Perl meets beats - gihyo.jp

用意するもの

• サンプルコード

  WEB+DB PRESS Vol.69のサポートページから！

• Perl徹底攻略

  是非、お手元に！

• CPANモジュールガイド

  cpanmのハマりどころを9ページに渡って網羅！

PDLで書き換えてみる

ミックス処理

• すべての要素に対する掛け算（音量の適用）

• 配列同士の足し算

クリップ処理

• 配列内の-1.0未満の要素を-1.0に、
  +1.0を超える要素を+1.0に書き換える

PDLで書き換えてみる

各チャンネルの波形を生成

PDLで書き換えてみる

すべての要素に対する掛け算（音量の適用）

PDLで書き換えてみる

配列同士の足し算

PDLで書き換えてみる

ミックス処理（Before）

my @samples = ();
foreach my $ch_info ( @beats ) {
    my $ch = create_channel( $bpm, $ch_info );
    my $vol = $ch_info->{vol};
    for (my $i=0; $i<scalar(@{$ch}); $i++) {
        $samples[$i] += ( $ch->[$i] * $vol );
    }
}

PDLで書き換えてみる

ミックス処理（After）

my $samples = zeros( 0 );
foreach my $ch_info ( @beats ) {
    my $ch = pdl(
        create_channel($bpm, $ch_info)
    ) * $ch_info->{vol};

    # ミックスするデータの長さを揃える
    ...

    $samples += $ch;
}

PDLで書き換えてみる

ミックス処理（After）

my $samples = zeros( 0 );
foreach my $ch_info ( @beats ) {
    my $ch = pdl(
        create_channel($bpm, $ch_info)
    ) * $ch_info->{vol};

    # ミックスするデータの長さを揃える
    if ( $samples->nelem < $ch->nelem ) {
        $samples = $samples->append( zeros($ch->nelem - $samples->nelem) );
    }
    elsif ( $ch->nelem < $samples->nelem ) {
        $ch = $ch->append( zeros($samples->nelem - $ch->nelem) );
    }

    $samples += $ch;
}

PDLで書き換えてみる

クリップ処理（Before）

@samples = map {
    ( 1.0 < $_ )
        ? 1.0
        : ( ($_ < -1.0) ? -1.0 : $_ );
} @samples;

PDLで書き換えてみる

クリップ処理（After）

$samples = $samples->clip( -1, 1 );

まとめ

• 少しすっきりして、実測で30%くらい改善

• PDLからPerlへはこんな感じ

  use v5.10;
  use PDL;
  
  my $a = pdl( 1, 2, 3 );
  say $a; # [1 2 3]
  
  say join( ',', list($a) ); # 1,2,3
  
  my $ary_ref = unpdl( $a );
  say join( ',', @{$ary_ref} ); # 1,2,3
          

ご静聴、ありがとうございました